;; 2. Description: Exp distr., time splits, 5 thetas, rerun 254, NEW DATASET
;; x1. Author: user
; Duplicated from: run249.mod

;*******************************************************************************
;         CsA dataset  -  PD analysis: time to first acute rejection
;*******************************************************************************

$PROBLEM CsA PD - time to first acute rejection

$INPUT ID  XDAT1=DROP  XTIME=DROP           ;; take out date and time
       FLAG  EVID  DV  DDOSE  WTNDDOSE
       AGE  SEX  DIAG  TIME  CONTIME=DROP   ;; call TSTX TIME!
       FSTREC=DROP  WT  HT  SKR  AUC
       ICL  IV2  IQ3  IV3  IQ4  IV4  IKA  IF1
       DIAT  DON  DONA  DONS  HLAA  HLAD
       CMVD  CMVR  CIT  SIMU  TXNU
       IMM1  IMM2  CAL  BETA  BPLM
       cfbWT  cfbHT  cfbSKR

$DATA  Simulated_CsA_dataset_PD_model_110830_SIMULATED.csv    IGNORE=@
       IGNORE=(FLAG.EQ.5)      ;; ignore 2nd AR
       IGNORE=(FLAG.EQ.6)      ;; ignore 3rd AR
       IGNORE=(FLAG.EQ.7)      ;; ignore 4th AR
       IGNORE=(FLAG.EQ.9)      ;; ignore GFR
       IGNORE=(TIME.LT.0)      ;; ignore everything occuring before tx

$SUBROUTINE ADVAN=6 TOL=6

$MODEL COMP=(HAZARD)

$PK

;~~~ Simulation ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
   ; Sim_start : add for simulation
     ; RTTE = 0
   ; Sim_end
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

  CL  = ICL
  V2  = IV2
  Q3  = IQ3
  V3  = IV3
  Q4  = IQ4
  V4  = IV4
  KA  = IKA
  F1  = IF1

                LAM  = THETA(1)  *EXP(ETA(1))
  IF(TIME>5)    LAM  = THETA(2)  *EXP(ETA(1))
  IF(TIME>8)    LAM  = THETA(3)  *EXP(ETA(1))
  IF(TIME>25)   LAM  = THETA(4)  *EXP(ETA(1))
  IF(TIME>100)  LAM  = THETA(5)  *EXP(ETA(1))

$DES
                LAMT = THETA(1)
  IF(T>5)       LAMT = THETA(2)
  IF(T>8)       LAMT = THETA(3)
  IF(T>25)      LAMT = THETA(4)
  IF(T>100)     LAMT = THETA(5)

  DADT(1) = LAMT

$ERROR

;=== RTTE Model ================================================================
;
   IF(NEWIND.NE.2) OLDCHZ=0

   CHZ = A(1)-OLDCHZ                            ;; cumulative hazard

;~~~ Simulation ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
   ; Sim_start : remove from simulation model
     IF(EVID.NE.2) OLDCHZ = A(1)
   ; Sim_end
;
   ; Sim_start : add for simulation
   ; OLDCHZ = A(1)
   ; Sim_end
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
   SUR = EXP(-CHZ)

   HAZNOW = LAM

   Y = SUR*HAZNOW

   IF(FLAG.EQ.8) Y = SUR

;===============================================================================

;~~~ Simulation ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
   ; Sim_start : add for simulation
     ; IF(ICALL.EQ.4) THEN
       ; CALL RANDOM (2,R)
       ; DV   = 0
       ; RTTE = 0
       ; IF(FLAG.EQ.8)  RTTE = 1
       ; IF(FLAG.EQ.11) RTTE = 1
       ; IF(R.GT.SUR) THEN
         ; DV   = 1
         ; RTTE = 1
       ; ENDIF
     ; ENDIF
   ; Sim_end
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

$THETA  (0,0.00464924)  ; th1
$THETA  (0,0.0578174)   ; th2   >5
$THETA  (0,0.0186561)   ; th5   >8
$THETA  (0,0.00475348)  ; th4   >25
$THETA  (0,0.000127165) ; th5   >100
;
$OMEGA  0  FIX
;
;~~~ Simulation ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
; Sim_start : add for simulation
; $SIMULATION (5555555) (44444 UNIFORM) ONLYSIM  NOPREDICTION  SUB=100
$ESTIM MAXEVAL=0 METHOD=0 LIKE PRINT=1 MSFO=msfb272
; Sim_end
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~


;$COV PRINT=E

;$TABLE ID FLAG TIME SUR DDOSE EVID NOPRINT ONEHEADER FILE=sdtab272
;$TABLE ID ICL IV2 IQ3 IV3 IQ4 IV4 IKA IF1 NOPRINT ONEHEADER FILE=patab272
;$TABLE ID AGE WT HT DDOSE WTNDDOSE NOPRINT ONEHEADER FILE=cotab272
;$TABLE ID DIAG DON DONA NOPRINT ONEHEADER FILE=catab272

;~~~ Simulation ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
; Sim_start : add for simulation
; $TABLE ID FLAG DV TIME RTTE
; DDOSE WTNDDOSE
; NOPRINT NOAPPEND ONEHEADER FILE=fullsimtab272
; Sim_end
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~