;; 1. Based on: 2278
$PROBLEM    PD-model Budesonide/ACTH/Cortisol 
$DATA       Simulated_ACTH_Cortisol.csv IGNORE=# NREC=762
$INPUT      ID OCC TIME AMT EVID CMT CLOC CORT ACTH OMDV TYPE ICL IV
            IKA SORT SLOP DROP DV
$SUBROUTINE ADVAN6 TOL=9
$MODEL      COMP=(PK) COMP=(ACTH) COMP=(CORT)
$PK 
;---------------------------BUDESONIDE PK MODEL---------------
CL=ICL
V=IV
K=CL/V
KA=IKA
S1=V 
F1=1
IF (TYPE.EQ.1) F1=0
;---------------------------ACTH SURGE-----------

SA1=THETA(1)
SW1=THETA(2)
Pt=THETA(3)


SA2=THETA(11)
Pt3=THETA(12)
;----------------EFFECT PART - INHIB OF KIN---------------
KOUT=THETA(4)*EXP(ETA(2))
IMAX=THETA(5)
IC50=THETA(6)*EXP(ETA(1))
JC50=THETA(6)*EXP(ETA(1))
JMAX=THETA(10)
BASE=THETA(9)*EXP(ETA(3))
KIN  =BASE*KOUT
;---------------------------------------------------------

F2=0
;----------------CORT-----------------
ROUT =THETA(16)*EXP(-ETA(4))
AMAX =THETA(13)*EXP(ETA(4))
A50  =THETA(14)*EXP(-ETA(2))
GAMMA=THETA(15)
;--------------DIFFERENTIAL EQUATIONS-------------------
Pt2=THETA(3)+24
$DES 
DADT(1)=-K*A(1)
CONC=A(1)/V
SUR1=SA1/(((T-Pt )/SW1)**4+1)
SUR2=SA1/(((T-Pt2)/SW1)**4+1)
SUR3=SA2/(((T-Pt3)/SW1)**4+1)
DRG1=(1-(IMAX*CONC/(IC50+CONC)))
DRG2=(1-(JMAX*CONC/(JC50+CONC)))
DADT(2)=KIN*DRG1+(SUR1+SUR2+SUR3)*DRG2-KOUT*A(2)

EACT=AMAX*(A(2)**GAMMA)/(A(2)**GAMMA+A50**GAMMA)
DADT(3)=ROUT*(EACT-A(3))
;-----------------ERROR---------------------------------

$ERROR 
CP=A(1)/V
DRUG=IMAX*CP/(IC50+CP)
             IPRED=A(2)
IF(CMT.EQ.3) IPRED=A(3)
             W=SQRT(THETA(7)**2+THETA(8)**2*IPRED*IPRED)
IF(CMT.EQ.3) W=SQRT(THETA(17)**2+THETA(18)**2*IPRED*IPRED)
IRES=DV-IPRED
IWRES=IRES/W
             Y=IPRED+W*EPS(1)
;----------------
$ESTIMATION MAX=0 PRINT=1 MSFO=msf2278 METH=1 INTER
;$COVARIANCE
$THETA  (0,87.0316)     ; SA1
$THETA  (0,1.32061)     ; SW1
$THETA  (0,23.2851)     ; Pt
$THETA  (0,4.68023)     ; KOUT_ACTH
$THETA  (0,0.276872,1)  ; IMAX
$THETA  (0.005,0.324762); IC50
$THETA  0.001 FIX       ; ADD_ERROR_ACTH
$THETA  (0.001,0.324961); PROP_ERROR_ACTH
$THETA  (0,2.58051)     ; BASE
$THETA  1 FIX           ; JMAX
$THETA  (0,10)          ; SA2
$THETA  (25,32.2962,40) ; Pt3
;----CORT-----------------
$THETA  (0,814.546) ; AMAX
$THETA  (0,4.96084) ; A50
$THETA  (0,4.09935) ; GAMMA
$THETA  (0,0.366505); KOUT_CORTISOL
$THETA  .1 FIX      ; ADD_ERROR
$THETA  (0,0.330059); PROP_ERROR
$OMEGA  2.88402  ;     IC50
$OMEGA 0.142285  ; KOUT_A50
$OMEGA 0.0720674 ; BASE_ACTH
$OMEGA 0.244295  ; ROUT_AMAX
$SIGMA  1  FIX ; SIGMA