;; 1. Based on: 6046
;; 2. Description:
;; x2. Author: user

$PROBLEM    6063
$INPUT      ID         ;ID
            TIME       ;Time in hours
            DV         ;Dependent variable (logarithmic )
            AMT        ;Dose amount (in nmol unit in this example)
            MDV        ;Missing dependent variable (1=dose and concentrations below limit of quantification)
            EVID       ;Event ID record
            CMT        ;Compartment (1=dose,2=oseltamivir (OS),3=oseltamvir carboxylate (OC))
            OCC        ;Dose occasion
            BW         ;Covariate total body weight in kilogram
            CCL        ;Covariate creatinine clearance in mL/min
            OB         ;Covariate obesity (0=non-obese, 1=obese)

$DATA       Simulated_run2.csv    ;Dose (nmol), CP (nmol/L)
            IGNORE=@

$SUBROUTINE ADVAN5 TRANS1
$MODEL      COMP=(1)   ;(DEPOT DOSE)
            COMP=(2)   ;(CONCENTRATION OS)
            COMP=(3)   ;(CONCENTRATION OC)
            COMP=(4)   ;(TRANSIT COMPARTMENT FOR DELAYED CONVERSION OF OS TO OC)

$PK

;------------------------------------Age covariate-----------------------------------------------------------------------------------
CMCCL = ( 1 + THETA(10)*(CCL - 72.7))    ; Linear covariate relationship for creatinine clearance
CMCOV=CMCCL
;----------------------------------------------------------------------------------------------------------------------------------------

;=============== Between-occasion variability ======================;
  OCC0 = 0
  OCC1 = 0

  IF(OCC.EQ.0) OCC0 = 1   ; First dose occasion
  IF(OCC.EQ.1) OCC1 = 1   ; Second dose occasion

  BOVV2   = ETA(8)*OCC0 + ETA(9)*OCC1     ; IOV for OS volume of distribution
  BOVKA   = ETA(10)*OCC0 + ETA(11)*OCC1   ; IOV for OS absorption rate
  BOVKM   = ETA(12)*OCC0 + ETA(13)*OCC1    ; IOV for metabolism rate constant

;===================================================================;

  TVCL  = THETA(1);                                 ;Population OS clearance
  CL    = TVCL*EXP(ETA(1));                         ;Individual OS clearance

  TVV2  = THETA(2);                                 ;Population OS volume of distribution
  V2    = TVV2*EXP(ETA(2)+BOVV2);                   ;Individual OS volume of distribution

  TVKA  = THETA(3);                                 ;Population absorption rate constant
  KA    = TVKA*EXP(ETA(3)+BOVKA);                   ;Individual absorption rate constant

  TVCM  = THETA(4);                                 ;Population OC clearance
  TVCM  = TVCM*CMCOV                                ;Population OC clearance with covariate effect
  CM    = TVCM*EXP(ETA(4));                         ;Individual OC clearance

  TVV3  = THETA(5);                                 ;Population OC volume of distribution
  V3    = TVV3*EXP(ETA(5));                         ;Individual OC volume of distribution

  TVF1  = THETA(6);                                 ;Population OS relative oral availability
  F1    = TVF1*EXP(ETA(6));                         ;Individual OS relative oral availability

  TVKM  = THETA(7);                                 ;Population metabolism rate constant
  KM    = TVKM*EXP(ETA(7)+BOVKM)                    ;Individual metabolism rate constant


  S2    = V2
  S3    = V3

  K12   = KA                                        ; Absorption rate constant          (COMP 1 --> 2)
  K24   = CL/V2                                     ; Elimination rate constant for OS  (COMP 2 --> 4)
  K43   = KM                                        ; metabolism rate constant          (COMP 4 --> 3)
  K30   = CM/V3                                     ; Elimination rate constant for OC  (COMP 3 --> 0)

$ERROR

  IF(AMT.GT.0)    DTIM  = TIME                      ; Calculation of time-after-dose (TAD)
                  TAD   = TIME-DTIM                 ; Calculation of time-after-dose (TAD)
                  
  IF(CMT.EQ.2) THEN
  IPRED = A(2)/S2                                   ;Predicted plasma concentration of OS
  W     = THETA(8);                                 ;Additive residual error of OS on log scale
  ENDIF

  IF(CMT.EQ.3) THEN
  IPRED = A(3)/S3                                   ;Predicted plasma concentration of OC
  W     = THETA(9);                                 ;Additive residual error of OC on log scale
  ENDIF

  IF(IPRED.GT.0) IPRED = LOG(IPRED)

  Y     = IPRED+W*EPS(1)
  IRES  = DV-IPRED
  IWRES = IRES/W

$THETA  
 (0,585)   ; 1.TVCL
 (0,1110)  ; 2.TVV2
 (0,2.8)   ; 3.TVKA
 (0,20.6)  ; 4.TVCM
 (0,160)   ; 5.TVV3
 1 FIX     ; 6.TVF1
 (0,2.15)  ; 7.TVKM
 (0,0.430) ; 8.TVW1
 (0,0.160) ; 9.TVW2
 (-1,0.005,1) ; 10.CMCCL

$OMEGA
 0.0300  ;   1.IIV CL
 0 FIX   ;   2.IIV V2
 0 FIX   ;   3.IIV KA
 0 FIX   ;   4.IIV CM
 0.0360  ;   5.IIV V3
 0.0320  ;   6.IIV F1
 0 FIX   ;   7.IIV KM

$OMEGA  BLOCK(1) 0.03    ; BOV-V2_OCC0
$OMEGA  BLOCK(1) SAME    ; BOV-V2_OCC1

$OMEGA  BLOCK(1) 0.70    ; BOV-KA_OCC0
$OMEGA  BLOCK(1) SAME    ; BOV-KA_OCC1

$OMEGA  BLOCK(1) 0.175   ; BOV-KM_OCC0
$OMEGA  BLOCK(1) SAME    ; BOV-KM_OCC1

$SIGMA  1  FIX

$ESTIMATION MAXEVAL=0 PRINT=5 POSTHOC METHOD=1 INTER

$COV PRINT=E

$TABLE
  ID TIME TAD OB DV AMT CMT MDV EVID CL V2 KA CM V3 F1 KM W
  ETA1 ETA2 ETA3 ETA4 ETA5 ETA6 ETA7
  IPRED PRED IRES IWRES CWRES
  NOPRINT ONEHEADER FILE=mytab6063                                                ;Personal table file (specify what to be printed)