;; 1. Based on: Run061
;; 2. Description: GENTATOTAAL 2C M3 ETA OP CL V1 TBW op V1 TBW OP CL OMBL
;; x1. Author: CS

$PROBLEM GENTA 
$INPUT ID	TIME	AMT	RATE	DV	MDV	WT	LLOQ	

$DATA Simulated_data_gentamicin_obese.prn IGNORE=@
$SUBROUTINE ADVAN3 TRANS4

$PK
  TVCL   = THETA(1)*((WT/70)**THETA(6)); TVCL	
   TVV1    = THETA(2)*((WT/70)**THETA(5)); TVV1
  TVQ	=	THETA(3); TVQ
  TVV2	=	THETA(4); TVV2

;
CL = TVCL*EXP(ETA(1)) 
V1 = TVV1*EXP(ETA(2)) 
Q = TVQ*EXP(ETA(3))
V2 = TVV2*EXP(ETA(4))
 

  S1   = V1 ; conversion of amount in comp-1 to concentration
;
ET1=ETA(1)
ET2=ETA(2)
ET3=ETA(3)
ET4=ETA(4)


$THETA

(0, 0.0892)  ; TVCL
(0, 11.9)  ; TVV
(0, 0.0848)  ; Q
(0, 7.29)  ; V2
(0, 1.25)  ; exp v1
(0, 0.729)  ; EXP CL

(0,0.159) ; SD PROPORTIONAL ERR
(0, 0.206)  ; SD ADD

$OMEGA BLOCK(2)
 0.0323  ; CL ETA 1
 0.0316 0.0362 ; COVAR ET1-ET2, V1 ETA 2
$OMEGA
0 FIX;ETA 3
0 FIX ;ETA 4
$ERROR

IPRED  = F



PROP=THETA(7)*F ; proportional part 
ADD=THETA(8) ; additive part 
SD=SQRT(PROP*PROP + ADD*ADD) ; Standard deviation using proportional res error

IF(DV.GE.LLOQ)THEN ; LLOQ IS DEFINED IN DATASET
   F_FLAG=0
   Y=F+SD*ERR(1)   ; COMBINED ERROR MODEL
ELSE ; 
   F_FLAG=1
   Y=PHI((LLOQ-F)/SD)
ENDIF

IRES   = DV - IPRED
IWRES = IRES/SD

$SIGMA 
1 FIX     ; ERR 1 
;0.1      ; ERR 2


;$SIM (123456) ONLYSIM SUBPROBLEMS=1
$ESTIMATION METHOD=1 INTER MAXEVAL=0 NOABORT NUMERICAL SLOW POSTHOC LAPLACIAN; calculation method
;$COVARIANCE SLOW PRINT=E; standard error of estimate is calculated

$TABLE ID TIME IPRED IWRES CWRES AMT TVCL CL TVV1 V1 TVV2 V2 ET1 ET2 MDV  WT  NOPRINT ONEHEADER FILE=sdtab074_ddmore