;; 1. Description: Chloroquine PK model

;;----------------------------------------------------------------------------;;
;; Mahidol-Oxford Tropical Medicine Research Unit
;; Project name: Chloroquine - CQPRQ interactions
;; date: 2020-05-22
;;----------------------------------------------------------------------------;;

$PROBLEM    1
$INPUT
  ID TIME DV AMT EVID CMT MDV TBW COMED

$DATA  Simulated_run1.csv IGNORE = @
$SUBROUTINE ADVAN5 TRANS1

$MODEL
  COMP  = (1)                                                                   ;Absorption compartment
  COMP  = (2)                                                                   ;CQ
  COMP  = (3)                                                                   ;CQ peripheral compartment 1
  COMP  = (4)                                                                   ;CQ peripheral compartment 2
  COMP  = (5)                                                                   ;Transit compartment 1
  COMP  = (6)                                                                   ;Transit compartment 2
  COMP  = (7)                                                                   ;Transit compartment 3

$PK
;=============== Between-occasion variability - MTT ======================;
  OCC1 = 0
  OCC2 = 0

  IF(COMED.EQ.0) OCC1 = 1
  IF(COMED.EQ.1) OCC2 = 1

  BOVMT = ETA(9)*OCC1 + ETA(10)*OCC2
;===================================================================;

  TVCL  = THETA(1)*((TBW/61.9)**0.75);         ;Typical value
  CL    = TVCL*EXP(ETA(1))                     ;Individual parameter estimate

  TVV2  = THETA(2)*((TBW/61.9)**1.0);          ;Typical value
  V2    = TVV2*EXP(ETA(2))                     ;Individual parameter estimate

  TVMTT = THETA(3);                            ;Typical value
  MTT   = TVMTT*EXP(ETA(3)+BOVMT)              ;Individual parameter estimate

  TVF1  = THETA(4);                            ;Typical value
  F1    = TVF1*EXP(ETA(4))                     ;Individual parameter estimate

  TVQ1  = THETA(5)*((TBW/61.9)**0.75);         ;Typical value
  Q1    = TVQ1*EXP(ETA(5))                     ;Individual parameter estimate

  TVV4  = THETA(6)*((TBW/61.9)**1.0);           ;Typical value
  V4    = TVV4*EXP(ETA(6))                     ;Individual parameter estimate

  TVQ2  = THETA(7)*((TBW/61.9)**0.75);          ;Typical value
  Q2    = TVQ2*EXP(ETA(7))                     ;Individual parameter estimate

  TVV5  = THETA(8)*((TBW/61.9)**1.0);          ;Typical value
  V5    = TVV5*EXP(ETA(8))                     ;Individual parameter estimate

  NN    = 3                                    ; Number of transit compartments
  KTR   = (NN+1)/MTT                           ;Calculate ktr

  K15   = KTR                                  ;Transfer between absorption and first transit compartment
  K56   = KTR                                  ;Transfer between first and second transit compartment
  K67   = KTR                                  ;Transfer between second and third transit compartment
  K72   = KTR                                  ;Transfer between thrid transit compartment and central CQ compartment

  K20   = (CL/V2)                              ;Elimination of CQ
  K23   = Q1/V2                                ;Distribution into first periferal compartment
  K32   = Q1/V4                                ;Distribution from first periferal compartment
  K24   = Q2/V2                                ;Distribution into second periferal compartment
  K42   = Q2/V5                                ;Distribution from second periferal compartment

  S2    = V2                                   ;Scaling factor in central CQ compartment

$ERROR
  IF(CMT.EQ.2) THEN
    IPRED = A(2)/S2                            ;Calculate CQ individual prediction
    W = SQRT(SIGMA(1,1))                       ;Define CQ residuals
  ENDIF

  IPRED = LOG(IPRED)                           ;Calculate logarithmic individual predictions

  IRES = DV-IPRED
  IWRES = IRES/W

  Y = IPRED + EPS(1)

$THETA
(0, 37.8)                 ;1.TVCL
(0, 2020)                 ;2.TVV2
(0, 1.26)                 ;3.TVMTT
(1) FIX                   ;4.TVF1
(0, 20.3)                 ;5.TVQ1
(0, 6740)                 ;6.TVV4
(0, 174)                  ;7.TVQ2
(0, 3270)                 ;8.TVV5

$OMEGA
 0.0236                   ;1.IIV CL
 0.0685                   ;2.IIV V2
 0.151                    ;3.IIV MTT
 0.0111                   ;4.IIV F1
 0 FIX                    ;5.IIV Q1
 0 FIX                    ;6.IIV V4
 0 FIX                    ;7.IIV Q2
 0 FIX                    ;8.IIV V5
$OMEGA BLOCK(1) 0.166     ;9-10 BOV-MTT_OCC1
$OMEGA  BLOCK(1) SAME

$SIGMA
 0.0806                   ;1.RUV OS

$ESTIMATION MAXEVAL=0 PRINT=5 POSTHOC METHOD=1 INTER MCETA=500 NSIG=1